Ads by ArduinoGetStarted.com
Arduino - DC Motor - Limit Switch
In this Arduino tutorial, we are going to learn how to use Arduino to control DC motor by limit switch and L298N driver. In detail, we are going to learn:
- How to stop DC motor when a limit switch is touched
- How to change the direction of DC motor when a limit switch is touched
- How to change the direction of DC motor when two limit switches is touched
Hardware Required
Or you can buy the following sensor kits:
| 1 | × | DIYables Sensor Kit (30 sensors/displays) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Please note: These are Amazon affiliate links. If you buy the components through these links, We will get a commission at no extra cost to you. We appreciate it.
About DC Motor and Limit Switch
If you do not know about DC motor and limit switch (pinout, how it works, how to program ...), learn about them in the following tutorials:
- Arduino - Limit Switch tutorial
- Arduino - Controls DC Motor tutorial
Wiring Diagram
This tutorial provides the Arduino codes for two cases: One DC motor + one limit switch, One DC motor + two limit switches.
- Wiring diagram between the DC motor and a limit switch
This image is created using Fritzing. Click to enlarge image
- Wiring diagram between the DC motor and two limit switches
This image is created using Fritzing. Click to enlarge image
Arduino Code - Stop DC Motor by a Limit Switch
The below code make a DC motor spin infinitely and stop immediately when a limit switch is touched
/*
* Created by ArduinoGetStarted.com
*
* This example code is in the public domain
*
* Tutorial page: https://arduinogetstarted.com/tutorials/arduino-dc-motor-limit-switch
*/
#include <ezButton.h>
#define ENA_PIN 7 // The Arduino pin connected to the EN1 pin L298N
#define IN1_PIN 6 // The Arduino pin connected to the IN1 pin L298N
#define IN2_PIN 5 // The Arduino pin connected to the IN2 pin L298N
ezButton limitSwitch(A1); // create ezButton object that attach to pin A1
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // set debounce time to 50 milliseconds
// initialize digital pins as outputs.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH); // max speed
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
}
void loop() {
limitSwitch.loop(); // MUST call the loop() function first
if (limitSwitch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
digitalWrite(IN1_PIN, LOW); // stop motor
digitalWrite(IN2_PIN, LOW); // stop motor
}
}
Quick Steps
- Connect Arduino to PC via USB cable
- Open Arduino IDE, select the right board and port
- Navigate to the Libraries icon on the left bar of the Arduino IDE.
- Search “ezButton”, then find the button library by ArduinoGetStarted.com
- Click Install button to install ezButton library.
- Copy the above code and open with Arduino IDE
- Click Upload button on Arduino IDE to upload code to Arduino
- If the wiring is correct, you will see the motor rotates clockwise direction.
- Touch the limit switch
- You will see the motor is stopped immediately
- The result on Serial Monitor looks like below
COM6
The limit switch: TOUCHED
The DC motor is STOPPED
The DC motor is STOPPED
The DC motor is STOPPED
The DC motor is STOPPED
Autoscroll
Clear output
9600 baud
Newline
Code Explanation
Read the line-by-line explanation in comment lines of code!
Arduino Code - Change Direction of DC Motor by a Limit Switch
The below code make a DC motor spin infinitely and change its direction when a limit switch is touched
/*
* Created by ArduinoGetStarted.com
*
* This example code is in the public domain
*
* Tutorial page: https://arduinogetstarted.com/tutorials/arduino-dc-motor-limit-switch
*/
#include <ezButton.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
// constants won't change
#define ENA_PIN 7 // The Arduino pin connected to the EN1 pin L298N
#define IN1_PIN 6 // The Arduino pin connected to the IN1 pin L298N
#define IN2_PIN 5 // The Arduino pin connected to the IN2 pin L298N
ezButton limitSwitch(A1); // create ezButton object that attach to pin A1
int direction = DIRECTION_CW;
void setup() {
Serial.begin(9600);
limitSwitch.setDebounceTime(50); // set debounce time to 50 milliseconds
// initialize digital pins as outputs.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH); // max speed
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
}
void loop() {
limitSwitch.loop(); // MUST call the loop() function first
if (limitSwitch.isPressed()) {
Serial.println(F("The limit switch: TOUCHED"));
direction *= -1; // change direction
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW) {
Serial.println(F("CLOCKWISE"));
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
} else {
Serial.println(F("ANTI-CLOCKWISE"));
digitalWrite(IN1_PIN, LOW); // control motor A spins anti-clockwise
digitalWrite(IN2_PIN, HIGH); // control motor A spins anti-clockwise
}
}
}
Quick Steps
- Copy the above code and open with Arduino IDE
- Click Upload button on Arduino IDE to upload code to Arduino
- If the wiring is correct, you will see the motor spins in the clockwise direction.
- Touch the limit switch
- You will see the DC motor's direction is changed to the anti-clockwise
- Touch the limit switch again
- You will see the DC motor's direction is changed to clockwise
- The result on Serial Monitor looks like below
COM6
The limit switch: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline
Arduino Code - Change Direction of DC Motor by two Limit Switches
The below code make a DC motor spin infinitely and change its direction when one of two limit switches is touched
/*
* Created by ArduinoGetStarted.com
*
* This example code is in the public domain
*
* Tutorial page: https://arduinogetstarted.com/tutorials/arduino-dc-motor-limit-switch
*/
#include <ezButton.h>
#define DIRECTION_CCW -1
#define DIRECTION_CW 1
#define ENA_PIN 7 // The Arduino pin connected to the EN1 pin L298N
#define IN1_PIN 6 // The Arduino pin connected to the IN1 pin L298N
#define IN2_PIN 5 // The Arduino pin connected to the IN2 pin L298N
ezButton limitSwitch_1(A0); // create ezButton object that attach to pin A0
ezButton limitSwitch_2(A1); // create ezButton object that attach to pin A1
int direction = DIRECTION_CW;
int prev_direction = DIRECTION_CW;
void setup() {
Serial.begin(9600);
limitSwitch_1.setDebounceTime(50); // set debounce time to 50 milliseconds
limitSwitch_2.setDebounceTime(50); // set debounce time to 50 milliseconds
// initialize digital pins as outputs.
pinMode(ENA_PIN, OUTPUT);
pinMode(IN1_PIN, OUTPUT);
pinMode(IN2_PIN, OUTPUT);
digitalWrite(ENA_PIN, HIGH); // max speed
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
}
void loop() {
limitSwitch_1.loop(); // MUST call the loop() function first
limitSwitch_2.loop(); // MUST call the loop() function first
if (limitSwitch_1.isPressed()) {
direction *= -1; // change direction
Serial.println(F("The limit switch 1: TOUCHED"));
}
if (limitSwitch_2.isPressed()) {
direction *= -1; // change direction
Serial.println(F("The limit switch 2: TOUCHED"));
}
if (prev_direction != direction) {
Serial.print(F("The direction -> "));
if (direction == DIRECTION_CW) {
Serial.println(F("CLOCKWISE"));
digitalWrite(IN1_PIN, HIGH); // control motor A spins clockwise
digitalWrite(IN2_PIN, LOW); // control motor A spins clockwise
} else {
Serial.println(F("ANTI-CLOCKWISE"));
digitalWrite(IN1_PIN, LOW); // control motor A spins anti-clockwise
digitalWrite(IN2_PIN, HIGH); // control motor A spins anti-clockwise
}
prev_direction = direction;
}
}
Quick Steps
- Copy the above code and open with Arduino IDE
- Click Upload button on Arduino IDE to upload code to Arduino
- If the wiring is correct, you will see the motor spins in the clockwise direction.
- Touch the limit switch 1
- You will see the DC motor's direction is changed to anti-clockwise
- Touch the limit switch 2
- You will see the DC motor's direction is changed to clockwise
- The result on Serial Monitor looks like below
COM6
The limit switch 1: TOUCHED
The direction -> ANTI-CLOCKWISE
The limit switch 2: TOUCHED
The direction -> CLOCKWISE
Autoscroll
Clear output
9600 baud
Newline
Video Tutorial
We are considering to make the video tutorials. If you think the video tutorials are essential, please subscribe to our YouTube channel to give us motivation for making the videos.
