Arduino - Touch Sensor
Touch sensor (also called touch button or touch switch) is widely used to control devices (e,g. touchable lamp). It has the same functionality as a button. It is used instead of the button on many new devices because it makes the product look neat.
In this tutorial, we will learn how to use the touch sensor with Arduino.
Hardware Required
Or you can buy the following kits:
| 1 | × | DIYables STEM V3 Starter Kit (Arduino included) | |
| 1 | × | DIYables Sensor Kit (18 sensors/displays) |
Disclosure: Some links in this section are Amazon affiliate links. If you make a purchase through these links, we may earn a commission at no extra cost to you.
Additionally, some links direct to products from our own brand, DIYables .
Additionally, some links direct to products from our own brand, DIYables .
About Touch Sensor
Pinout
Touch sensor has 3 pins:
- GND pin: needs to be connected to GND (0V)
- VCC pin: needs to be connected to VCC (5V or 3.3v)
- SIGNAL pin: is an output pin: LOW when it is NOT touched, HIGH when it is touched. This pin needs to be connected to Arduino's input pin.
How It Works
- When the sensor is NOT touched, the sensor's SIGNAL pin is LOW
- When the sensor is touched, the sensor's SIGNAL pin is HIGH
Arduino - Touch Sensor
The touch sensor's SIGNAL pin is connected to an Arduino's input pin.
By reading the state of Arduino's pin (configured as an input pin), we can detect whether the touch sensor is touched or not.
Wiring Diagram
This image is created using Fritzing. Click to enlarge image
How To Program For Touch Sensor
- Initializes the Arduino pin to the digital input mode by using pinMode() function. For example, pin 7
pinMode(7, INPUT_PULLUP);
- Reads the state of the Arduino pin by using digitalRead() function.
int inputState = digitalRead(7);
※ NOTE THAT:
There are two wide-used use cases:
- The first: If the input state is HIGH, do something. If the input state is LOW, do another thing in reverse.
- The second: If the input state is changed from LOW to HIGH (or HIGH to LOW), do something.
Depending on the application, we choose one of them. For example, in case of using a touch sensor to control an LED:
- If we want the LED to be ON when the sensor is touched and OFF when the sensor is NOT touched, we SHOULD use the first use case.
- If we want the LED to be toggle between ON and OFF each time we touch the sensor, we SHOULD use the second use case.
- How to detect the state change from LOW to HIGH
// constants won't change. They're used here to set pin numbers:
const int SENSOR_PIN = 7; // the Arduino's input pin that connects to the sensor's SIGNAL pin
// Variables will change:
int lastState = LOW; // the previous state from the input pin
int currentState; // the current reading from the input pin
void setup() {
// initialize serial communication at 9600 bits per second:
Serial.begin(9600);
// initialize the Arduino's pin as aninput
pinMode(SENSOR_PIN, INPUT);
}
void loop() {
// read the state of the the input pin:
currentState = digitalRead(SENSOR_PIN);
if(lastState == LOW && currentState == HIGH)
Serial.println("The sensor is touched");
// save the the last state
lastState = currentState;
}
Touch Sensor - Arduino Code
We will run four example codes:
- Reads the value from the touch sensor and print to the Serial Monitor.
- Controls LED according to the sensor's state.
- Detects the sensor is touched or released.
- Toggles LED when the sensor is touched (This is the most common-used).
Reads the value from the touch sensor and print to the Serial Monitor
/*
* Created by ArduinoGetStarted.com
*
* This example code is in the public domain
*
* Tutorial page: https://arduinogetstarted.com/tutorials/arduino-touch-sensor
*/
// constants won't change. They're used here to set pin numbers:
const int SENSOR_PIN = 7; // the Arduino's input pin that connects to the sensor's SIGNAL pin
void setup() {
// initialize serial communication at 9600 bits per second:
Serial.begin(9600);
// initialize the Arduino's pin as aninput
pinMode(SENSOR_PIN, INPUT);
}
void loop() {
// read the state of the the input pin:
int state = digitalRead(SENSOR_PIN);
// print state to Serial Monitor
Serial.println(state);
}
Quick Steps
- Copy the above code and open with Arduino IDE
- Click Upload button on Arduino IDE to upload code to Arduino
- Touch your finger to the sensor and release.
- See the result on Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
0
0
0
1
1
1
1
1
1
0
0
Controls LED according to the sensor's state
If the sensor is touched, turn LED on. If the sensor is not touched, turn LED off.
/*
* Created by ArduinoGetStarted.com
*
* This example code is in the public domain
*
* Tutorial page: https://arduinogetstarted.com/tutorials/arduino-touch-sensor
*/
// constants won't change. They're used here to set pin numbers:
const int SENSOR_PIN = 7; // the Arduino's input pin that connects to the sensor's SIGNAL pin
void setup() {
// initialize serial communication at 9600 bits per second:
Serial.begin(9600);
// initialize the Arduino's pin as aninput
pinMode(SENSOR_PIN, INPUT);
// initialize digital pin LED_BUILTIN as an output.
pinMode(LED_BUILTIN, OUTPUT);
}
void loop() {
// read the state of the the input pin:
int state = digitalRead(SENSOR_PIN);
// control LED according to the sensor's state
digitalWrite(LED_BUILTIN, state);
}
Quick Steps
- Copy the above code and open with Arduino IDE
- Click Upload button on Arduino IDE to upload code to Arduino
- Touch your finger to the sensor and keep touching.
- See LED state ⇒ LED should be on.
- Release your finger from the sensor.
- See LED state ⇒ LED should be off.
Detects the sensor is touched or released
// constants won't change. They're used here to set pin numbers:
const int SENSOR_PIN = 7; // the Arduino's input pin that connects to the sensor's SIGNAL pin
// Variables will change:
int lastState = LOW; // the previous state from the input pin
int currentState; // the current reading from the input pin
void setup() {
// initialize serial communication at 9600 bits per second:
Serial.begin(9600);
// initialize the Arduino's pin as aninput
pinMode(SENSOR_PIN, INPUT);
}
void loop() {
// read the state of the the input pin:
currentState = digitalRead(SENSOR_PIN);
if(lastState == LOW && currentState == HIGH)
Serial.println("The sensor is touched");
else if(lastState == HIGH && currentState == LOW)
Serial.println("The sensor is is released");
// save the the last state
lastState = currentState;
}
Quick Steps
- Copy the above code and open with Arduino IDE
- Click Upload button on Arduino IDE to upload code to Arduino
- Touch your finger to the sensor and keep touching.
- See the result on Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
The sensor is touched
- Release your finger from the sensor.
- See the result on Serial Monitor.
8
Serial.println("Hello World!");
Message (Enter to send message to 'Arduino Uno' on 'COM15')
New Line
9600 baud
The sensor is touched
The sensor is is released
Toggles LED when the sensor is touched.
/*
* Created by ArduinoGetStarted.com
*
* This example code is in the public domain
*
* Tutorial page: https://arduinogetstarted.com/tutorials/arduino-touch-sensor
*/
// constants won't change. They're used here to set pin numbers:
const int SENSOR_PIN = 7; // the Arduino's input pin that connects to the sensor's SIGNAL pin
// Variables will change:
int lastState = LOW; // the previous state from the input pin
int currentState; // the current reading from the input pin
int ledState = LOW; // the current LED state
void setup() {
// initialize serial communication at 9600 bits per second:
Serial.begin(9600);
// initialize the Arduino's pin as aninput
pinMode(SENSOR_PIN, INPUT);
// initialize digital pin LED_BUILTIN as an output.
pinMode(LED_BUILTIN, OUTPUT);
}
void loop() {
// read the state of the the input pin:
currentState = digitalRead(SENSOR_PIN);
if(lastState == LOW && currentState == HIGH){
// toggle LED state
if(ledState == LOW)
ledState = HIGH;
else if(ledState == HIGH)
ledState = LOW;
// control LED
digitalWrite(LED_BUILTIN, ledState);
}
// save the the last state
lastState = currentState;
}
Quick Steps
- Copy the above code and open with Arduino IDE
- Click Upload button on Arduino IDE to upload code to Arduino
- Touch your finger to the sensor and release.
- See LED state ⇒ LED should be on.
- Touch your finger to the sensor and release.
- See LED state ⇒ LED should be off.
- Touch your finger to the sensor and release.
- See LED state ⇒ LED should be on.
Video Tutorial
We are considering to make the video tutorials. If you think the video tutorials are essential, please subscribe to our YouTube channel to give us motivation for making the videos.
The below video demo uses the below code. Note that the video shows Arduino Uno R4, but it works identically for Arduino Uno R3:
/*
* Created by ArduinoGetStarted.com
*
* This example code is in the public domain
*
* Tutorial page: https://arduinogetstarted.com/tutorials/arduino-touch-sensor
*/
// --- Hardware Pin Definitions ---
#define BUZZER_PIN 8
#define TOUCH_1_PIN 2 // Happy Birthday trigger
#define TOUCH_2_PIN 3 // Jingle Bells trigger
#define LED_A_PIN 4 // First indicator LED (Active-Low)
#define LED_B_PIN 5 // Second indicator LED (Active-Low)
// --- Musical Note Frequencies (Hz) ---
#define NOTE_C4 262
#define NOTE_D4 294
#define NOTE_E4 330
#define NOTE_F4 349
#define NOTE_G4 392
#define NOTE_A4 440
#define NOTE_A5 880
#define NOTE_B4 494
#define NOTE_C5 523
#define NOTE_D5 587
#define NOTE_E5 659
// --- Melody 1: Happy Birthday ---
const int happyBirthdayMelody[] = {
NOTE_C4, NOTE_C4, NOTE_D4, NOTE_C4, NOTE_F4, NOTE_E4,
NOTE_C4, NOTE_C4, NOTE_D4, NOTE_C4, NOTE_G4, NOTE_F4,
NOTE_C4, NOTE_C4, NOTE_C5, NOTE_A4, NOTE_F4, NOTE_E4, NOTE_D4,
NOTE_B4, NOTE_B4, NOTE_A4, NOTE_F4, NOTE_G4, NOTE_F4
};
const int happyBirthdayDurations[] = {
8, 8, 4, 4, 4, 2,
8, 8, 4, 4, 4, 2,
8, 8, 4, 4, 4, 4, 4,
8, 8, 4, 4, 4, 2
};
const int happyBirthdayLength = sizeof(happyBirthdayMelody) / sizeof(happyBirthdayMelody[0]);
// --- Melody 2: Jingle Bells ---
const int jingleBellsMelody[] = {
NOTE_E4, NOTE_E4, NOTE_E4, NOTE_E4, NOTE_E4, NOTE_E4,
NOTE_E4, NOTE_G4, NOTE_C4, NOTE_D4, NOTE_E4,
NOTE_F4, NOTE_F4, NOTE_F4, NOTE_F4, NOTE_F4, NOTE_E4, NOTE_E4,
NOTE_E4, NOTE_E4, NOTE_D4, NOTE_D4, NOTE_E4, NOTE_D4, NOTE_G4
};
const int jingleBellsDurations[] = {
4, 4, 2, 4, 4, 2,
4, 4, 4, 4, 1,
4, 4, 4, 4, 4, 4, 4,
8, 8, 4, 4, 4, 4, 2
};
const int jingleBellsLength = sizeof(jingleBellsMelody) / sizeof(jingleBellsMelody[0]);
// --- Function Prototypes ---
void playSong(const int melody[], const int durations[], int songLength);
void updateLeds(int noteIndex, bool isQuietNote);
void turnOffBothLeds();
/**
* @brief Initializes peripheral pins and system communication.
*/
void setup() {
Serial.begin(115200);
pinMode(TOUCH_1_PIN, INPUT);
pinMode(TOUCH_2_PIN, INPUT);
pinMode(BUZZER_PIN, OUTPUT);
pinMode(LED_A_PIN, OUTPUT);
pinMode(LED_B_PIN, OUTPUT);
// For Active-Low LEDs, setting pins HIGH turns them OFF on startup
turnOffBothLeds();
Serial.println(F("Active-Low LED Music Box Jukebox Ready."));
}
/**
* @brief Main execution loop checking for touch sensor triggers.
*/
void loop() {
if (digitalRead(TOUCH_1_PIN) == HIGH) {
Serial.println(F("Touch 1 detected: Playing Happy Birthday..."));
playSong(happyBirthdayMelody, happyBirthdayDurations, happyBirthdayLength);
}
else if (digitalRead(TOUCH_2_PIN) == HIGH) {
Serial.println(F("Touch 2 detected: Playing Jingle Bells..."));
playSong(jingleBellsMelody, jingleBellsDurations, jingleBellsLength);
}
}
/**
* @brief Iterates through the provided melody arrays to play the full song with LED sync.
* @param melody Array containing note frequencies.
* @param durations Array containing corresponding note lengths.
* @param songLength Total number of notes in the song.
*/
void playSong(const int melody[], const int durations[], int songLength) {
for (int thisNote = 0; thisNote < songLength; thisNote++) {
bool isQuietNote = (melody[thisNote] == 0);
int noteDuration = 1000 / durations[thisNote];
// Trigger Active-Low LED effect
updateLeds(thisNote, isQuietNote);
tone(BUZZER_PIN, melody[thisNote], noteDuration);
int pauseBetweenNotes = noteDuration * 1.30;
delay(pauseBetweenNotes);
noTone(BUZZER_PIN);
turnOffBothLeds(); // Drive both pins HIGH to turn off the LEDs
}
Serial.println(F("Song finished. LEDs reset to standby (HIGH)."));
}
/**
* @brief Logic switch designed for Active-Low configurations (LOW = ON, HIGH = OFF).
* @param noteIndex Current position in the melody array.
* @param isQuietNote Evaluation flag determining if the note produces no sound.
*/
void updateLeds(int noteIndex, bool isQuietNote) {
if (isQuietNote) {
turnOffBothLeds();
return;
}
// Alternating Active-Low pattern
if (noteIndex % 2 == 0) {
digitalWrite(LED_A_PIN, LOW); // LED A turns ON
digitalWrite(LED_B_PIN, HIGH); // LED B turns OFF
} else {
digitalWrite(LED_A_PIN, HIGH); // LED A turns OFF
digitalWrite(LED_B_PIN, LOW); // LED B turns ON
}
}
/**
* @brief Forces both LED control pins to HIGH, turning them OFF in Active-Low logic.
*/
void turnOffBothLeds() {
digitalWrite(LED_A_PIN, HIGH);
digitalWrite(LED_B_PIN, HIGH);
}